A következő példa ugyanazt a négyszöget hozza létre, mint az előző példa, de most 30 százalékkal eldönti a ShearAngle tulajdonsággal.

Dim Doc As Object

Dim Page As Object

Dim RectangleShape As Object

Dim Point As New com.sun.star.awt.Point

Dim Size As New com.sun.star.awt.Size



Point.x = 1000

Point.y = 1000

Size.Width = 10000

Size.Height = 10000



Doc = StarDesktop.CurrentComponent

Page = Doc.drawPages(0)

RectangleShape = Doc.createInstance("com.sun.star.drawing.RectangleShape")

RectangleShape.Size = Size

RectangleShape.Position = Point



RectangleShape.ShearAngle = 3000



Page.add(RectangleShape)

Keresés és csere

Ahogy a szöveges dokumentumokban is, úgy a rajzobjektumokban is lehet keresni és cserélni. Ez a funkció hasonló a szöveges dokumentumoknál a 6., Szöveges dokumentumok című fejezetben leírthoz. Viszont a rajzobjektumoknál a kereséshez használt leíróobjektum nem közvetlenül a dokumentumobjektumon keresztül van létrehozva, hanem a hozzá tartozó karakterszinten keresztül. A következő példa bemutatja a cserefolyamatot egy rajzban:

Dim Doc As Object

Dim Page As Object

Dim ReplaceDescriptor As Object

Dim I As Integer



Doc = StarDesktop.CurrentComponent

Page = Doc.drawPages(0)



ReplaceDescriptor = Page.createReplaceDescriptor()

ReplaceDescriptor.SearchString = "kutya"

ReplaceDescriptor.ReplaceString = "macska"



For I = 0 to Doc.drawPages.Count - 1

   Page = Doc.drawPages(I)

   Page.ReplaceAll(ReplaceDescriptor) 

Next I

A program először a dokumentum DrawPage objektumával létrehoz egy ReplaceDescriptor objektumot, majd ezt a leírót alkalmazza egy ciklusban a rajzdokumentum összes oldalára.

Bemutatók

A StarOffice-bemutatók a rajzdokumentumokon alapulnak. A bemutatóban minden oldal egy dia. A diák ugyanúgy, ahogy a normál rajzok, a dokumentumobjektum DrawPages listáján keresztül érhetők el. A com.sun.star.presentation.PresentationDocument szolgáltatás felelős a bemutatódokumentumok kezeléséért, és biztosítja a teljes com.sun.star.drawing.DrawingDocument szolgáltatást is.

A bemutatókkal végzett munka

A Presentation tulajdonság által biztosított rajzfunkciókon felül a bemutatódokumentum rendelkezik egy bemutatóobjektummal, amely hozzáférést biztosít a bemutatók főbb tulajdonságaihoz és vezérlési mechanizmusához. Például ez az objektum biztosít egy start metódust, amely elindítja a bemutatót.

Dim Doc As Object

Dim Presentation As Object

   

Doc = StarDesktop.CurrentComponent

Presentation = Doc.Presentation

Presentation.start()

A példában a program létrehoz egy Doc objektumot, amely az aktuális bemutatódokumentumra hivatkozik, majd létrehozza a hozzá tartozó bemutatóobjektumot. Az objektum start() metódusa elindítja a bemutatót, és az megjelenik.

A bemutatóobjektumok a következő metódusokat tartalmazzák:

• start - a bemutató indítása.

• end - a bemutató befejezése.

• rehearseTimings - elindítja a bemutatót az elejétől, és futásidőben állítja össze.

A következő tulajdonságok szintén elérhetők:

• AllowAnimations (logikai érték)- az animációk engedélyezése a bemutatókban.

• CustomShow (karakterlánc) - megadhatjuk a bemutató nevét, így hivatkozhatunk a névre a bemutatóban.

• FirstPage (karakterlánc) - annak a diának a neve, amellyel kezdeni akarjuk a bemutatót.

• IsAlwaysOnTop (logikai érték) - mindig a bemutatóablak lesz a legfelső a képernyőn.

• IsAutomatic (logikai érték) automatikusan végigmegy a bemutatóban.

• IsEndless (logikai érték) - újraindítja a bemutatót, ha az véget ér.

• IsFullScreen (logikai érték) - automatikusan teljes képernyős módban indítja el a bemutatót.

• IsMouseVisible (logikai érték) - megjeleníti az egérmutatót a bemutató közben.

• Pause (hosszú egész) - az az idő, amíg egy üres képernyő jelenik meg a bemutató vége után.

• StartWithNavigator (logikai érték) - megjeleníti a navigálóablakot, amikor a bemutató elindul.

• UsePn (logikai érték) - megjeleníti a mutatót a bemutató közben.