A szöveg csak azután szúrható be, miután a rajzobjektum hozzá lett adva az oldalhoz. A com.sun.star.drawing.Text szolgáltatással beállítható a rajzobjektum szövegének helye és formátuma. Az alábbiakban láthatók ennek a szolgáltatásnak a legfőbb tulajdonságai:

• TextAutoGrowHeight (logikai érték) - a rajzelem magasságát az általa tartalmazott szöveghez igazítja.

• TextAutoGrowWidth (logikai érték) - a rajzelem szélességét az általa tartalmazott szöveghez igazítja.

• TextHorizontalAdjust (enumeráció) - a szöveg vízszintes helye a rajzelemen belül (alapértelmezett értékek a com.sun.star.drawing.TextHorizontalAdjust tulajdonság szerint).

• TextVerticalAdjust (enumeráció) - a szöveg függőleges helye a rajzelemen belül (alapértelmezett értékek a com.sun.star.drawing.TextVerticalAdjust tulajdonság szerint).

• TextLeftDistance (hosszú egész) - a szöveg bal oldala és a rajzelem közti távolság századmilliméterben.

• TextRightDistance (hosszú egész) - a szöveg jobb oldala és a rajzelem közti távolság századmilliméterben.

• TextUpperDistance (hosszú egész) - a szöveg felső oldala és a rajzelem közti távolság századmilliméterben.

• TextLowerDistance (hosszú egész) - a szöveg alsó oldala és a rajzelem közti távolság századmilliméterben.

A következő példa bemutatja a fent említett tulajdonságok használatát.

Dim Doc As Object

Dim Page As Object

Dim RectangleShape As Object

Dim Point As New com.sun.star.awt.Point

Dim Size As New com.sun.star.awt.Size



Point.x = 1000

Point.y = 1000

Size.Width = 10000

Size.Height = 10000



Doc = StarDesktop.CurrentComponent

Page = Doc.drawPages(0)



RectangleShape = Doc.createInstance("com.sun.star.drawing.RectangleShape")

RectangleShape.Size = Size

RectangleShape.Position = Point



Page.add(RectangleShape)



RectangleShape.String = "Ez egy teszt."   ' Csak a Page.add után állhat!



RectangleShape.TextVerticalAdjust = com.sun.star.drawing.TextVerticalAdjust.TOP

RectangleShape.TextHorizontalAdjust = com.sun.star.drawing.TextHorizontalAdjust.LEFT



RectangleShape.TextLeftDistance = 300

RectangleShape.TextRightDistance = 300

RectangleShape.TextUpperDistance = 300

RectangleShape.TextLowerDistance = 300

Ez a program beszúr egy rajzelemet egy oldalra, majd szöveget ír a rajzobjektum bal felső sarkába a TextVerticalAdjust és a TextHorizontalAdjust tulajdonsággal. A szöveg széle és a rajzobjektum közti minimális távolság három milliméter.

Árnyéktulajdonságok

Árnyékot adhatunk a legtöbb rajzobjektumhoz a com.sun.star.drawing.ShadowProperties szolgáltatással. A szolgáltatás tulajdonságai:

• Shadow (logikai érték) - az árnyék aktiválása.

• ShadowColor (hosszú egész) - az árnyék színe.

• ShadowTransparence (rövid egész) - az árnyék átlátszósága.

• ShadowXDistance (hosszú egész) - az árnyék rajzobjektumtól mért függőleges távolsága századmilliméterben.

• ShadowYDistance (hosszú egész) - az árnyék rajzobjektumtól mért vízszintes távolsága századmilliméterben.

A következő példa létrehoz egy négyszöget egy árnyékkal, amely függőlegesen és vízszintesen 2 milliméterre van a négyszögtől. Az árnyék sötétszürkén jelenik meg, 50 százalékos átlátszósággal.

Dim Doc As Object

Dim Page As Object

Dim RectangleShape As Object

Dim Point As New com.sun.star.awt.Point

Dim Size As New com.sun.star.awt.Size



Point.x = 1000

Point.y = 1000

Size.Width = 10000

Size.Height = 10000



Doc = StarDesktop.CurrentComponent

Page = Doc.drawPages(0)



RectangleShape = Doc.createInstance("com.sun.star.drawing.RectangleShape")

RectangleShape.Size = Size

RectangleShape.Position = Point



RectangleShape.Shadow = True

RectangleShape.ShadowColor = RGB(192,192,192)

RectangleShape.ShadowTransparence = 50

RectangleShape.ShadowXDistance = 200 

RectangleShape.ShadowYDistance = 200



Page.add(RectangleShape)