A rajzobjektumok alapvető tulajdonságai

A rajzobjektumok magukban foglalják az alakzat- (négyszögek, körök stb.), vonal-és szövegobjektumokat. Ezek mindegyike rendelkezik számos azonos funkcióval, és támogatják a com.sun.star.drawing.Shape szolgáltatást. Ez a szolgáltatás meghatározza a rajzobjektum Size és Position tulajdonságát.

A StarOffice Basic számtalan más szolgáltatást is biztosít, amelyeken keresztül módosíthatjuk az olyan tulajdonságokat, mint például a formázás, valamint kitöltéseket használhatunk. A rendelkezésre álló formázási lehetőségek a rajzobjektum típusától függenek.

A következő példa létrehoz és beszúr egy négyszöget a rajzobjektumba:

Dim Doc As Object

Dim Page As Object

Dim RectangleShape As Object

Dim Point As New com.sun.star.awt.Point

Dim Size As New com.sun.star.awt.Size



Doc = StarDesktop.CurrentComponent

Page = Doc.drawPages(0)



Point.x = 1000

Point.y = 1000

Size.Width = 10000

Size.Height = 10000



RectangleShape = Doc.createInstance("com.sun.star.drawing.RectangleShape")

RectangleShape.Size = Size

RectangleShape.Position = Point



Page.add(RectangleShape)

Ez a példa a StarDesktop.CurrentComponent hívást használja annak megállapítására, hogy melyik dokumentum van megnyitva. Az így meghatározott dokumentumobjektum a drawPages(0) függvényhívással visszaadja a rajzobjektum első oldalát.

Ezután a program inicializál egy Point és egy Size struktúrát a rajzobjektum kezdőpontjával (bal felső sarok) és méretével. A hosszméretek századmilliméterben vannak megadva.

A program ezután a Doc.createInstance használatával létrehoz egy négyszöget a com.sun.star.drawing.RectangleShape szolgáltatás alapján. Végül a program a rajzobjektumot hozzárendeli egy oldalhoz a Page.add használatával.

Rajztulajdonságok

Ez a szakasz négy szolgáltatást ismertet, és mindegyiknél a példaprogram egy négyszög-rajzelemet használ a különböző formázási típusok bemutatására. A kitöltési tulajdonságok a com.sun.star.drawing.FillProperties szolgáltatásban vannak összegyűjtve.

A StarOffice a kitöltési terület négy fő formázási típusát ismeri fel. A legegyszerűbb az egyszínű kitöltés. A színátmenet és a vonalkázás már több színt is használ. A negyedik változat egy adott ábrát vetít a kitöltési területre.

Egy rajzobjektum kitöltési módját a FillStyle tulajdonság határozza meg. A használható értékeket a com.sun.star.drawing.FillStyle tartalmazza.

Egyszínű kitöltés

Az egyszínű kitöltés főtulajdonsága a

• FillColor (hosszú egész szám) - a terület kitöltési színe.

A kitöltési mód használatához a FillStyle tulajdonságot a SOLID kitöltési módra kell állítani.

A következő példa létrehoz egy négyszögalakzatot, és kitölti azt pirossal (RGB-érték: 255, 0, 0):

Dim Doc As Object

Dim Page As Object

Dim RectangleShape As Object

Dim Point As New com.sun.star.awt.Point

Dim Size As New com.sun.star.awt.Size



Point.x = 1000

Point.y = 1000

Size.Width = 10000

Size.Height = 10000



Doc = StarDesktop.CurrentComponent

Page = Doc.drawPages(0)



RectangleShape = Doc.createInstance("com.sun.star.drawing.RectangleShape")

RectangleShape.Size = Size

RectangleShape.Position = Point



RectangleShape.FillStyle = com.sun.star.drawing.FillStyle.SOLID

RectangleShape.FillColor = RGB(255,0,0)



Page.add(RectangleShape)