Számok, dátumok és szöveg formázása

A StarOffice számos előre definiált dátum- és időformátumot biztosít. Ezek mindegyike rendelkezik egy belső számmal, amelyet a NumberFormat tulajdonság használ cellák formázásához. A StarOffice a queryKey és a addNew metódust biztosítja a meglévő számformátumokhoz való hozzáféréshez és új számformátumok létrehozásához. A metódusokat a következő objektumhíváson keresztül lehet elérni:

NumberFormats = Doc.NumberFormats

A formátumot egy formátum-karakterlánc határozza meg, amelynek struktúrája hasonló a StarOffice Basic formázási funkciójának struktúrájához. Viszont van egy különbség: míg a parancsformátum angol rövidítéseket és tizedespontot, illetve karaktereket vár ezreselválasztóként, addig a NumberFormats objektum struktúrájában a területi beállításoknak megfelelő parancsformátumot kell megadni.

A következő példa úgy formázza a B2 cellát, hogy a számok három tizedesjeggyel jelennek meg, és a vesszőt használják ezreselválasztóként.

Dim Doc As Object

Dim Sheet As Object

Dim Cell As Object

Dim NumberFormats As Object

Dim NumberFormatString As String

Dim NumberFormatId As Long

Dim LocalSettings As New com.sun.star.lang.Locale



Doc = StarDesktop.CurrentComponent

Sheet = Doc.Sheets(0)

Cell = Sheet.getCellByPosition(1,1)



Cell.Value = 23400.3523565



LocalSettings.Language = "en"

LocalSettings.Country = "us"



NumberFormats = Doc.NumberFormats

NumberFormatString = "#,##0.000"



NumberFormatId = NumberFormats.queryKey(NumberFormatString, LocalSettings, True)

If NumberFormatId = -1 Then

   NumberFormatId = NumberFormats.addNew(NumberFormatString, LocalSettings)

End If



MsgBox NumberFormatId

Cell.NumberFormat = NumberFormatId

A StarOffice Calc Format Cells párbeszédablaka áttekintés nyújt a cellák különböző formázási lehetőségeiről.

Oldaltulajdonságok

Az oldaltulajdonságok olyan formázási lehetőségek, amelyek a dokumentum tartalmat, valamint vizuális elemeket, amelyek oldalról oldalra ismétlődnek, helyeznek el. Ezek közé tartoznak a következők:

• Papírformátumok

• Oldalmargók

• Fejlécek és láblécek

Az oldalformátumok definiálása eltér a más típusú formázásoktól. Míg a cellák, bekezdések és karakterek közvetlenül formázhatók, addig az oldalformátumok közvetetten is formázhatók oldalstílusok használatával. Például fejlécek és láblécek adhatók az oldalstílushoz.

A következő részek leírják a munkalap-oldalak főbb formázási lehetőségeit. A bemutatott stílusok közül több is elérhető a szöveges dokumentumoknál. A mindkét dokumentumtípusnál használható oldaltulajdonságok a com.sun.star.style.PageProperties szolgáltatásban vannak definiálva. A csak a munkafüzet-dokumentumoknál használható tulajdonságok a com.sun.star.sheet.TablePageStyle szolgáltatásban vannak definiálva.

Megjegyzés - A Microsoft Office-dokumentumok oldaltulajdonságait (oldalmargó, -keret stb.) a Worksheet objektum (Excel) vagy a Document objektum (Word) PageSetup objektuma definiálja. A StarOffice programban ezeket a tulajdonságokat az oldalstílus definiálja, amely viszont a hozzá tartozó dokumentumhoz van csatolva.

Oldalháttér

A com.sun.star.style.PageProperties szolgáltatás a következő tulajdonságokat definiálja az oldalháttér számára:

• BackColor (hosszú egész) - háttér színe.

• BackGraphicURL (karakterlánc) - a használni kívánt háttérkép URL-je.

• BackGraphicFilter (karakterlánc) - a háttérképet értelmező szűrő neve.

• BackGraphicLocation (enumeráció) - a háttérkép pozíciója (az enumerációnak megfelelően).

• BackTransparent (logikai érték) - átlátszó háttérkép.

Oldalformátum

Az oldalformátumot a com.sun.star.style.PageProperties szolgáltatás tulajdonságai határozzák meg:

• IsLandscape (logikai érték) - fekvő formátum.

• Width (hosszú egész) - az oldal szélessége századmilliméterben.

• Height (hosszú egész) - az oldal magassága századmilliméterben.

• PrinterPaperTray (karakterlánc) - használni kívánt nyomtatótálca neve.

A következő példa a "Default" oldalstílus méretét a DIN A5 fekvő formátumra (magasság: 14,8 cm, szélesség: 21 cm) állítja:

Dim Doc As Object

Dim Sheet As Object

Dim StyleFamilies As Object 

Dim PageStyles As Object

Dim DefPage As Object



Doc = StarDesktop.CurrentComponent

StyleFamilies = Doc.StyleFamilies

PageStyles = StyleFamilies.getByName("PageStyles")

DefPage = PageStyles.getByName("Default")



DefPage.IsLandscape = True

DefPage.Width = 21000

DefPage.Height = 14800