A removeRange metódus az ellentettje a insertCells metódusnak. Ez a metódus törli a CellRangeAddress struktúrában megadott cellatartományt a munkalapról.

Dim Doc As Object

Dim Sheet As Object

Dim CellRangeAddress As New com.sun.star.table.CellRangeAddress



Doc = StarDesktop.CurrentComponent

Sheet = Doc.Sheets(0)



CellRangeAddress.Sheet = 0

CellRangeAddress.StartColumn = 1

CellRangeAddress.StartRow = 1

CellRangeAddress.EndColumn = 2

CellRangeAddress.EndRow = 2



Sheet.removeRange(CellRangeAddress, com.sun.star.sheet.CellDeleteMode.UP)

Ez a példa eltávolítja a munkalapból a B2:C3 cellatartományt, és felfelé mozgatja az alatta lévő cellákat két sorral. Az eltávolítást típusát a com.sun.star.sheet.CellDeleteMode enumeráció egyik értéke határozza meg:

• NONE - az aktuális értékek a helyükön maradnak.

• UP - a beszúrási pozícióban és azalatt lévő értékek lefelé mozognak.

• LEFT - a beszúrási pozícióban és attól jobbra lévő értékek balra mozognak.

• ROWS - a beszúrási pozíció utáni sorok felfelé mozognak.

• COLUMNS - a beszúrási pozíció utáni oszlopok balra mozognak.

A XRangeMovement felület két további metódust biztosít a cellatartományok mozgatásához (moveRange) vagy másolásához (copyRange). A következő példa áthelyezi a B2:C3 tartományt, hogy az az A6 pozícióban kezdődjön:

Dim Doc As Object

Dim Sheet As Object

Dim CellRangeAddress As New com.sun.star.table.CellRangeAddress

Dim CellAddress As New com.sun.star.table.CellAddress



Doc = StarDesktop.CurrentComponent

Sheet = Doc.Sheets(0)



CellRangeAddress.Sheet = 0

CellRangeAddress.StartColumn = 1

CellRangeAddress.StartRow = 1

CellRangeAddress.EndColumn = 2

CellRangeAddress.EndRow = 2



CellAddress.Sheet = 0

CellAddress.Column = 0

CellAddress.Row = 5



Sheet.moveRange(CellAddress, CellRangeAddress)

A CellRangeAdress struktúrán felül a moveRange metódus egy com.sun.star.table.CellAddress struktúrát is vár, amely megadja a célterület kezdőpozícióját. A CellAddress metódus a következő értékeket használja:

• Sheet (rövid egész) - a munkalap száma (a számozás 0-val kezdődik).

• Column (rövid egész) - az oszlop száma (a számozás 0-val kezdődik).

• Row (rövid egész) - a sor száma (a számozás 0-val kezdődik).

A célterület cellatartományait mindig felülírja a moveRange metódus. Az InsertCells metódustól eltérően a removeRange metódusnál nincs automatikus mozgatást biztosító paraméter.

A copyRange metódus ugyanúgy működik, mint a moveRange metódus, kivéve, hogy a copyRange beszúrja a cella másolatát annak mozgatása helyett.

Megjegyzés - Funkciójukat tekintve a StarOffice Basic insertCell, a removeRange és a copyRange metódus hasonló, mint a VBA Range.Insert, Range.Delete és Range.Copy metódusa. Míg VBA-ban a metódusok a hozzájuk tartozó Range objektumra vonatkoznak, a StarOffice Basic programban a Sheet objektumra vonatkoznak.

Formázás

A munkafüzet-dokumentum tulajdonságokat és metódusokat biztosít a cellák és oldalak formázásához.