Fájlok másolása, átnevezése, törlése és létezésük ellenőrzése

A

FileCopy(Source, Destination)

létrehozza a Source fájl másolatát Destination néven.

A

Name OldName As NewName

függvénnyel átnevezhetjük az OldName fájlt NewName nevűre. Az As kulcsszó szintaxisa és az, hogy nincs vessző a függvényben a Basic nyelv gyökereire nyúlik vissza.

A

Kill(Filename)

törli a Filename fájlt. Ha egy könyvtárat akarunk törölni (annak fájljaival együtt), akkor használjuk az RmDir függvényt.

A FileExists függvénnyel megállapíthatjuk, hogy egy fájl létezik-e:

If FileExists(Filename) Then 

   MsgBox "A fájl létezik."

End If

Fájltulajdonságok beolvasása és módosítása

A fájlokkal végzett munka során néha fontos, hogy meg tudjuk állapítani a fájl tulajdonságait, az utolsó módosítás idejét és a fájl hosszát.

A

Dim Attr As Integer

Attr = GetAttr(Filename)

függvény a fájl néhány tulajdonságát adja vissza. A visszaadott érték egy bitmaszk, amely a következő értékeket tartalmazhatja:

• 1 : csak olvasható fájl

• 16 : könyvtárnév

A

Dim FileMask As Integer

Dim FileDescription As String

   

FileMask = GetAttr("test.txt")

If (FileMask AND 1) > 0 Then

   FileDescription = FileDescription & " csak olvasható "

End IF



If (FileMask AND 16) > 0 Then

   FileDescription = FileDescription & " könyvtár "

End IF



If FileDescription = "" Then

   FileDescription = " normál "

End IF



MsgBox FileDescription

példa beolvassa a test.txt fájl bitmaszkját, és megállapítja, hogy a fájl csak olvasható-e, és hogy könyvtár-e. Ha egyik sem, akkor a FileDescription változóhoz a "normál" karakterláncot rendeli.

Megjegyzés - A VBA-ban használt jelzők (rejtett, rendszer, archív és kötetnév) nem támogatottak a StarOffice Basic programban, mert ezek Windows-specifikus tulajdonságok, és csak részlegesen érhetők el más operációs rendszereken.

A SetAttr függvénnyel módosíthatók egy fájl tulajdonságai. A

SetAttr("test.txt", 1)

függvény csak olvashatóvá teszi a fájlt. Ha a fájl csak olvasható, akkor ez a következő függvénnyel állítható vissza:

SetAttr("test.txt", 0)

A fájl módosításának utolsó dátuma és ideje beolvasható a FileDateTime függvénnyel. Itt a dátum a rendszer területi beállításainak megfelelően lesz formázva.

FileDateTime("test.txt")   ' Utolsó módosítás dátumának és idejének beolvasása

A FileLen függvény beolvassa egy fájl hosszát bájtban (hosszú egész számként).

FileLen("test.txt")      ' Beolvassa egy fájl hosszát bájtban.

Szövegfájlok írása és módosítása

A StarOffice Basic számtalan módszert biztosít a fájlok olvasására és írására. A következő példák a szövegfájlokkal (és nem a szöveges dokumentumokkal) végzett munkát mutatják be.

Szövegfájlok írása

Mielőtt egy szövegfájlhoz hozzá lehetne férni, meg kell nyitni azt. Ehhez egy szabad fájlkezelő szükséges, amely egyértelműen azonosítja a fájlt a hozzáféréshez.

A FreeFile függvénnyel lehet szabad fájlkezelőt létrehozni. Ezt a kezelőt kapja meg paraméterként az Open utasítás, amely megnyitja a fájlt. Ha szövegfájlként akarjuk megnyitni a fájlt, az Open utasítást a következőképpen kell használni:

Open Filename For Output As #FileNo

A Filename egy karakterlánc, amely tartalmazza a fájl nevét. A FileNo egy kezelő , amelyet a FreeFile függvény hozott létre.

Ha a fájl meg van nyitva, akkor a Print utasítással lehet írni bele sorról sorra:

Print #FileNo, "Ez egy tesztsor."

A FileNo itt is a fájlkezelő. A második paraméter a fájlba egy sorként menteni kívánt szöveg.

Ha az írási folyamat befejeződött, a fájlt le kell zárni a Close utasítással:

    Close #FileNo

A fájlkezelőt itt is meg kell adni.

A következő példa bemutatja egy szövegfájl megnyitását, írását és bezárását.

Dim FileNo As Integer

Dim CurrentLine As String

Dim Filename As String



Filename = "c:\data.txt"      ' Fájlnév megadása

FileNo = Freefile             ' Szabad fájlkezelő létrehozása



Open Filename For Output As #FileNo        ' Fájl megnyitása (írási módban)

Print #FileNo, "Ez egy tesztsor."          ' Sor mentése

Print #FileNo, "Ez egy másik tesztsor."    ' Sor mentése

Close #FileNo                              ' Fájl bezárása