Megjegyzés - A hét első napja vasárnap.

Rendszerdátum és -idő beolvasása

A StarOffice Basic programban a következő függvényekkel lehet beolvasni rendszeridőt és -dátumot:

• Date - visszaadja az aktuális dátumot.

• Time - visszaadja az aktuális időt.

• Now - visszaadja az aktuális időpontot (dátum és idő együtt).

Fájlok és könyvtárak

A fájlokkal végzett munka egyike egy alkalmazás alapvető feladatainak. A StarOffice API számtalan objektumot biztosít az Office-dokumentumok létrehozásához, megnyitásához és módosításához. Ezekről további információért lásd: Fejezet 4, A StarOffice API bemutatása. Ettől függetlenül előfordulhat, hogy közvetlenül el akarjuk érni a fájlrendszert, keresni akarunk könyvtárakban, vagy szerkeszteni szövegfájlokat. A StarOffice Basic futásidejű programkönyvtára számos alapfüggvényt biztosít ezekhez a feladatokhoz.

Megjegyzés - Néhány DOS-specifikus fájl- és könyvtárfüggvény már nem támogatott a StarOffice 8 programban, vagy csak korlátozottan használható. Például a ChDir, ChDrive és a CurDir függvény nem használható. Néhány DOS-specifikus tulajdonság már nem használható olyan függvényekben, amelyek fájltulajdonságokat várnak paraméterként (például a rejtett fájlok és rendszerfájlok megkülönböztetéséhez). Erre a változásra azért volt szükség, hogy a StarOffice platformfüggetlenségét a lehető legmagasabb szinten biztosítani lehessen.

Fájlok kezelése

Keresés a könyvtárakban

A StarOffice Basic Dir függvényével fájlokat és alkönyvtárakat kereshetünk a könyvtárakban. Az első meghíváskor a Dir függvény első paramétereként meg kell adni egy karakterláncot, amely tartalmazza az elérési utat, amelyben keresni akarunk. A Dir második paramétere megadja a keresendő fájlt vagy könyvtárat. A StarOffice Basic visszaadja az első megtalált könyvtárbejegyzést. A következő elem megkereséséhez a Dir függvényt paraméterek nélkül kell meghívni. Ha a Dir nem talál több elemet, üres karakterláncot ad vissza.

A következő példa bemutatja, hogyan érhető el az összes fájl egy könyvtárban a Dir függvény használatával. Az eljárás menti az egyes fájlneveket az AllFiles változóban, majd megjeleníti azt egy üzenetablakban.

Sub ShowFiles

   Dim NextFile As String

   Dim AllFiles As String



   AllFiles = ""

   NextFile = Dir("C:\", 0)



   While NextFile  <> ""

      AllFiles = AllFiles & Chr(13) &  NextFile 

      NextFile  = Dir

   Wend



   MsgBox AllFiles

End Sub

A 0 második paraméterként a Dir függvényben biztosítja, hogy a Dir csak a fájlok neveit adja vissza, a könyvtárakat nem. Itt a következő paraméterek adhatók meg:

• 0 : normál fájlokat ad vissza

• 16 : alkönyvtárak

A következő példa majdnem azonos az előzővel, de a Dir függvény a 16-ot kapja paraméterként, ami a mappa alkönyvtárait adja vissza fájlok helyett.

Sub ShowDirs

   Dim NextDir As String

   Dim AllDirs As String

   AllDirs = ""

   NextDir = Dir("C:\", 16)

   While NextDir <> ""

      AllDirs = AllDirs & Chr(13) &  NextDir

      NextDir  = Dir

   Wend

   MsgBox AllDirs

End Sub

Megjegyzés - A StarOffice Basic programban a Dir függvény a 16-os paraméterrel csak a mappa alkönyvtárait adja vissza. A VBA-ban a függvény a normál fájlok neveit is visszaadja, így további műveleteket kell végrehajtani, ha csak a fájlok neveire van szükség. A CompatibilityMode ( true ) függvény használatával a StarOffice Basic ugyanúgy működik, mint a VBA, és a Dir függvény a 16-os paramétert megadva az alkönyvtárakat és a fájlokat is visszaadja.

Megjegyzés - A VBA egyéb keresési lehetőségei, konkrétan a rejtett, rendszer, archív és kötet fájltípusokra való keresés nem létezik a StarOffice Basic programban, mert ezek a fájlrendszer-funkciók nem találhatók meg minden operációs rendszeren.

Megjegyzés - A Dir függvényben megadott elérési utak tartalmazhatják a * és a ? helyettesítő karaktert a VBA-ban és a StarOffice Basic programban is. Viszont a StarOffice Basic programban a * helyettesítő karakter csak a fájlnév és/vagy kiterjesztés végén állhat, de VBA-ban ez nem így van.

Könyvtárak létrehozása és törlése

A StarOffice Basic a MkDir függvényt biztosítja a könyvtárak létrehozásához.

    MkDir ("C:\SubDir1")

Ez a függvény könyvtárakat és alkönyvtárakat hoz létre. Az egy hierarchián belüli könyvtárak is létrehozhatók, ha szükséges. Ha például csak a C:\SubDir1 könyvtár létezik, akkor a

MkDir ("C:\SubDir1\SubDir2\SubDir3\")

függvényhívás létrehozza a C:\SubDir1\SubDir2 könyvtárat és a C:\SubDir1\SubDir2\SubDir3 könyvtárat is.

Az RmDir törli a könyvtárakat.

    RmDir ("C:\SubDir1\SubDir2\SubDir3\")

Ha a könyvtár alkönyvtárakat vagy fájlokat tartalmaz, akkor azok is törlődnek. Éppen ezért elővigyázatosan kell használni az RmDir függvényt.

Megjegyzés - A VBA-ban a MkDir és az RmDir függvény csak az aktuális könyvtárra vonatkozik. Ezzel szemben a StarOffice Basic programban a MkDir és az RmDir több könyvtárszint létrehozására vagy törlésére is használható.

Megjegyzés - A VBA-ban az RmDir hibaüzenetet jelenít meg, ha a könyvtár fájlt tartalmaz. A StarOffice Basic programban a könyvtár és abban minden fájl törölve lesz. Ha a CompatibilityMode ( true ) függvényt használjuk, akkor a StarOffice Basic úgy fog működni, mint a VBA.